Context Free 日記

頭の体操のような感じで Context Free の練習をば……

虹

カラフルなのが好き。

startshape Start
rule Start {
  40*{y 1 h 9 r 3} Branch {}
}
rule Branch {
  Dot {}
  Branch {x 1 h 1}
}
rule Dot {
  CIRCLE {s 2 z -2 b 0.2}
  CIRCLE {s 1.2 z -1}
  CIRCLE {s 1.05 b 1 sat 1}
}
rule Branch 0.1 {}

ぐしゃぐしゃ

単純な乱数なのに人が描いたみたいにぐしゃぐしゃ。

startshape Start
rule Start {10* {r 30 h 3 b 0.1} Line {}}
rule Line {
  SQUARE {s 0.5 sat 1 b 0.2}
  Line {y 0.5 r 2}
}
rule Line 0.01 {Line {r 90}}
rule Line 0.001 {}

ぐしゃぐしゃ２

skew で歪ませつつ，節目に丸を付けてインクが溜まったっぽくしてみた。

startshape Start
rule Start {
  10* {r 30 h 3 b 0.1} Line {h 200 sat 1 b 0.2}
}
rule Line {
  SQUARE {s 0.5}
  Line {y 0.5 r 2}
}
rule Line 0.01 {
  CIRCLE {s 1.05}
  Line {r 90 skew 10 0}
}
rule Line 0.001 {}

ぐしゃ緑

新緑をイメージしたバリエーション。

startshape Start
rule Start {
  10* {r 30 x 30 h 3 b 0.1} Line {h 100 sat 1 b 0.2}
}
rule Line {
  SQUARE {s 0.5}
  Line {y 0.5 r 2}
}
rule Line 0.01 {
  CIRCLE {s 1.05}
  Line {r 90}
}
rule Line 0.01 {
  CIRCLE {s 10 z -1 b 1 sat -0.8 skew 30 0}
  Line {r -90}
}
rule Line 0.001 {}

Mac 版の Context Free にはアニメーションレンダリング機能がある。レンダリングの過程をアニメーションにするという単純なものなのだけれど，これもなかなか面白い。